VRay Runtime Error with 3DS Max 2011 Design (German) and VRay.

[denx]

Hi!

Whenever I try to reset the Material Editor of 3DS Max 2011 Design with VRay SP5 I get the error you can find in the attachment.

Everything works fine with 3DS Max 2010 Design and SP4a.

The complete Script-PopUp looks like this:

-- MacroScript File
-- Created:       Feb 09 2005
-- Last Modified: Feb 25 2005
-- Medit Utilities
-- Version: 3dsmax 8
-- Author: Alexander Esppeschit Bicalho, Discreet
-- Modified: Alexander Esppeschit Bicalho, Discreet
--***********************************************************************************************
-- MODIFY THIS AT YOUR OWN RISK

/* History

Feb 09 - created script
Feb 10 - fixed problem where defaults.ini uses Hex number and ClassID is an Int
Feb 10 - added Restore Medit Slots script
Feb 11 - added Localization Notes
Feb 25 - added Condense Medit
Feb 25 - moved functions to meditfunctions.ms in StdScripts

NOTE TO LOCALIZATION
Only the headers should be localized

*/

macroScript clear_medit_slots 
enabledIn:#("MAX", "VIZ")
	category:"Medit Tools" 
	internalCategory:"Medit Tools"
	ButtonText:"Material-Editor-Felder zurücksetzen" 
	tooltip:"Material-Editor-Felder zurücksetzen"
(


on execute do
(
	defaultMtlLibFile = MeditUtilities.getDefaultLibraryFile()
	if defaultMtlLibFile != undefined do
	(
		defaultMtlLib = loadTempMaterialLibrary defaultMtlLibFile
		global _meditMaterialsBeforeReset = #()
		for i in 1 to meditMaterials.count do
		(	
			append _meditMaterialsBeforeReset meditMaterials[i]
			if i <= defaultMtlLib.count then
				meditMaterials[i] = defaultMtlLib[i]
			else
				meditMaterials[i] = defaultMtlLib[defaultMtlLib.count]
		)
	)
)

)

macroScript restore_medit_slots 
enabledIn:#("MAX", "VIZ")
	category:"Medit Tools" 
	internalCategory:"Medit Tools"
	ButtonText:"Material-Editor-Felder wiederherstellen" 
	tooltip:"Material-Editor-Felder wiederherstellen"
(

on isEnabled do (if classof _meditMaterialsBeforeReset == Array do _meditMaterialsBeforeReset.count > 0)

on execute do
(
	if _meditMaterialsBeforeReset.count == meditMaterials.count do
	(
		for i in 1 to meditMaterials.count do
		(	
			meditMaterials[i] = _meditMaterialsBeforeReset[i]
		)
		_meditMaterialsBeforeReset = undefined
	)
)

)

macroScript condense_medit_slots 
enabledIn:#("MAX", "VIZ")
	category:"Medit Tools" 
	internalCategory:"Medit Tools"
	ButtonText:"Material-Editor-Felder komprimieren" 
	tooltip:"Material-Editor-Felder komprimieren"
(


on execute do
(
	defaultMtlLibFile = MeditUtilities.getDefaultLibraryFile()
	if defaultMtlLibFile != undefined do
	(
		defaultMtlLib = loadTempMaterialLibrary defaultMtlLibFile

		usedMtls = #()
		for i in 1 to meditMaterials.count do
		(
			if MeditUtilities.isMaterialInUse meditMaterials[i] == true do
				append usedMtls meditMaterials[i]
		)
		global _meditMaterialsBeforeReset = #()
		for i in 1 to meditMaterials.count do
		(	
			append _meditMaterialsBeforeReset meditMaterials[i]
			if i <= usedMtls.count then
				meditMaterials[i] = usedMtls[i]
			else if i <= defaultMtlLib.count then
				meditMaterials[i] = defaultMtlLib[i]
			else
				meditMaterials[i] = defaultMtlLib[defaultMtlLib.count]
		)
	)
)

)

macroScript basic_material_editor
enabledIn:#("MAX", "VIZ")
	category:"Medit Tools" 
	internalCategory:"Medit Tools"
	ButtonText:"Kompakter Material-Editor..." 
	tooltip:"Kompakter Material-Editor..."
(


on execute do
(
-- close sme if needed and open Medit
	maxOps.mtlDlgMode = 0
	if (sme.IsOpen()) do sme.Close()

	-- Safe to call redundantly. Will restore window if minimized.
	matEditor.Open()
)

)

macroScript advanced_material_editor
enabledIn:#("MAX", "VIZ")
	category:"Medit Tools" 
	internalCategory:"Medit Tools"
	ButtonText:"Erweiterter Material-Editor..." 
	tooltip:"Erweiterter Material-Editor..."
(


on execute do
(
-- close Medit if needed and open sme
	maxOps.mtlDlgMode = 1
	if (matEditor.IsOpen()) do matEditor.Close()

	-- Safe to call redundantly. Will restore window if minimized.
	sme.Open()
)

)

I reinstalled VRay SP5 a few times now.

What could be the reasen / what could be a solution?

Greetings and thanks!

[jacksc02]

it sounds like this issue here-
http://www.chaosgroup.com/forums/vbu...aleditor-reset

[denx]

Oh, you are right. I did not find any related threads. Thanks.

[vlado]

Yep; we are looking into this; for now, just do not use the MAX.vray preset.

Best regards,
Vlado

[denx]

for now, just do not use the MAX.vray preset.

OK, thanks for your answer.