Vray Fur Styler Not Functioning?....

[joelly3d]

Hello,
I've been trying to get the Fur Styler to work and am following this tutorial: https://docs.chaosgroup.com/display/VMAYA/V-Ray+Fur+Styler+Setup+Tutorial but it doesn't seem to work at all.

I was going to automate this tutorial, and made a script to do all the steps for me. The script works fine, but fur styling painting has no effect.

//Creates and connects new fur sets and nodes for quick VRayFur styling
//STEP1: Select the mesh and add VRayFur if you haven't already.
//STEP2: Adjust fur as needed.
//STEP3: Select the mesh and run the code below....

$selectedMesh = `ls -sl`;
//Make Color Sets
$colorSetDir = `polyColorSet -create -clamped 0 -rpt RGBA -colorSet ("VRayFurInitialDir_"+$selectedMesh[0])`;
$colorSetBend = `polyColorSet -create -clamped 0 -rpt RGBA -colorSet ("VRayFurInitialBend_"+$selectedMesh[0])`;
//Make Shading Nodes
$thisTexDir = `shadingNode -asTexture VRayVertexColors -name ("VRayVertexColors_Dir_"+$selectedMesh[0])`;
$thisTexBend = `shadingNode -asTexture VRayVertexColors -name ("VRayVertexColors_Bend_"+$selectedMesh[0])`;
$thisPlaceDir = `shadingNode -asUtility place2dTexture -name ("Placement_"+$thisTexDir)`;
$thisPlaceBend = `shadingNode -asUtility place2dTexture -name ("Placement_"+$thisTexBend)`;
setAttr ($thisTexDir+".type") 1;
setAttr ($thisTexDir+".defaultColor") -type double3 0.5 0.5 0.5 ;
setAttr ($thisTexBend+".type") 1;
setAttr ($thisTexBend+".defaultColor") -type double3 0.5 0.5 0.5 ;
setAttr -type "string" ($thisTexDir+".name") $colorSetDir;
setAttr -type "string" ($thisTexBend+".name") $colorSetBend;
//Connect Nodes
connectAttr ($thisPlaceDir+".outUV") ($thisTexDir+".uv");
connectAttr ($thisPlaceDir+".outUvFilterSize") ($thisTexDir+".uvFilterSize");
connectAttr -force ($thisTexDir+".outColor") ($selectedMesh[0]+"_vrayFurProperties.initDirTex");
connectAttr ($thisPlaceBend+".outUV") ($thisTexBend+".uv");
connectAttr ($thisPlaceBend+".outUvFilterSize") ($thisTexBend+".uvFilterSize");
connectAttr -force ($thisTexBend+".outColor") ($selectedMesh[0]+"_vrayFurProperties.bendDirTex");
//Finish Up
select -r $selectedMesh;
colorSetEditor;

After that you can run the styler and should be able to start painting direction and bend. Am I missing something or is fur styling tool not working? Using VRay Next For Maya 2020.4 update 2.2 v4.30.02

Any insight appreciated.

[hermit.crab]

Have you switched the viewport renderer to Legacy Default, so you can see the brush?

[joelly3d]

Yeah i can see the brush, but painting does nothing to the fur in bend or direction mode.

[hermit.crab]

Your script does not seem to apply the Vertex Color nodes to the VRayFur correctly. Replace with this code for line 24 and line 27:

connectAttr -force ($thisTexDir+".outColor") ("vrayFurProperties.initDirTex");
connectAttr -force ($thisTexBend+".outColor") ("vrayFurProperties.bendDirTex");

Note that you need to use IPR in order to see the styler's effect.

[joelly3d]

Ah... stupid force command! Thanks.

[joelly3d]

Okay, painting seems to work now, but for some reason the fur effect is on the backface, like adding the vertex color nodes (or any texture) flips the normals. For example... if you make a simple disc, apply a cloth default texture and use that as the direction it flips it to the bottom. Any ideas for that? Seems like the demo didn't have this issue.

There is a note in the tutorial that says this, but mine doesn't seemt o correct itself as stated link:

As soon as you begin grooming the fur with the Styler, it should correct itself from what was seen in the previous render and point in the current direction.

//Creates and connects new fur sets for VRay Fur styling
//STEP1: Select the mesh and add VRay fur if you haven't already.
//STEP2: Adjust fur as needed.
//STEP3: Select the mesh and run the code below....

//Naming
string $selectedMesh[] = `ls -sl`;
string $setNameDir = "VRayFurInitialDir_"+$selectedMesh[0];
string $setNameBend = "VRayFurInitialBend_"+$selectedMesh[0];
//Make Color Sets
$colorSetDir = `polyColorSet -create -clamped 0 -rpt RGBA -colorSet $setNameDir`;
$colorSetBend = `polyColorSet -create -clamped 0 -rpt RGBA -colorSet $setNameBend`;
//Direction Nodes
$thisTexDir = `shadingNode -asTexture VRayVertexColors -name $setNameDir`;
setAttr ($thisTexDir+".type") 1;
setAttr -type "string" ($thisTexDir+".name") $setNameDir;
setAttr ($thisTexDir+".defaultColor") -type double3 0.5 0.5 0.5 ;
$thisPlaceDir = `shadingNode -asUtility place2dTexture -name ($setNameDir+"_placement")`;
connectAttr -force ($thisPlaceDir+".outUV") ($thisTexDir+".uv");
connectAttr -force ($thisPlaceDir+".outUvFilterSize") ($thisTexDir+".uvFilterSize");
connectAttr -force ($thisTexDir+".outColor") ($selectedMesh[0]+"_vrayFurProperties.initDirTex");
//Bend Nodes
$thisTexBend = `shadingNode -asTexture VRayVertexColors -name $setNameBend`;
setAttr ($thisTexBend+".type") 1;
setAttr -type "string" ($thisTexBend+".name") $setNameBend;
setAttr ($thisTexBend+".defaultColor") -type double3 0.5 0.5 0.5 ;
$thisPlaceBend = `shadingNode -asUtility place2dTexture -name ($setNameBend+"_placement")`;
connectAttr -force ($thisPlaceBend+".outUV") ($thisTexBend+".uv");
connectAttr -force ($thisPlaceBend+".outUvFilterSize") ($thisTexBend+".uvFilterSize");
connectAttr -force ($thisTexBend+".outColor") ($selectedMesh[0]+"_vrayFurProperties.bendDirTex");
//Finish Up
select -r $selectedMesh;
colorSetEditor;

[hermit.crab]

There does seem to be something the matter when creating the setup through scripting. I've logged an issue for developer investigation (internal bug-tracker id: VMAYA-10092). Creating the setup manually seems to work as intended, though; better do it like that for now.