output passes to separate folders

[sandykoufax]

http://www.scriptspot.com/3ds-max/sc...nts-to-folders
Dunno it's exactly what you want and I didn't tried it. So I don't know it works well with V-Ray

[joconnell]

Well, all options I need are exposed to maxscript, but works totally heraticaly. sometimes works, sometimes not, sometimes do the opposite ... nothing robust

For some reason, the choice between a 16 bit float and 32 bit float EXR isn't exposed to maxscript - likewise the option of saving it as RGBA, Integer and so on aren't exposed. Not a huge problem but anyway.

[duke2]

Seconding what Rend said except with FrameStamp'y syntax:
%outputPath//%name_%elementName.%extension

... on second thought, that looks a bit messy, maybe Rend's version is better
[outputPath]//[name]_[elementName].[extension]

[gandhics]

Try RPManager...

[Dave_Wortley]

For some reason, the choice between a 16 bit float and 32 bit float EXR isn't exposed to maxscript - likewise the option of saving it as RGBA, Integer and so on aren't exposed. Not a huge problem but anyway.

From the Maxscript Help

<bool>fopenexr.setLayerOutputFormat <integer>layer <integer>format

Returns the output format of the layer specified by the first argument to the type specified by the second argument.

Possible values for the second argument are

0 - FLOAT32

1 - FLOAT16

2 - INT32

EXAMPLE:
Here is an example of setting the Main Layer's Output Format and Type:
fopenexr.setLayerOutputFormat 0 0 -- set Main Render to FLOAT32
fopenexr.setLayerOutputType 0 1 -- set Main Render to RGB

[Rens]

Yes all EXR options are settable through maxscript, even more than through the UI.

The reason why this sometimes works and sometimes not is probably because you need to actually write a file to disk first for the settings to be locked in. This is how max bitmap IO works unfortunately.

Try this, it's a basic script I wrote a while back. This will allow you to set the EXR settings for 3ds max file output and render elements. Doesn't work for VRay outputs yet. Also there's no way that I know to read out the settings from an existing render element, so there's no feedback on what the elements are currently set to.

It assumes you already have your output set to the correct location, this doesn't change the file's location, only the EXR settings!

try destroyDialog dlgSetEXRSettings
	catch()


aElems = #()
append aElems "Max FileOut"

objRmgr = maxOps.GetCurRenderElementMgr()
iElemC = objRmgr.NumRenderElements()
for n = 0 to (iElemC-1) do
(
	sElem = (objRmgr.getrenderelement n).elementName
	append aElems sElem
)


rollout dlgSetEXRSettings "SetExrSettings_v001_rh" width:368 height:600
(
	MultiListBox mlbOut "EXR Outputs" items:aElems pos:[16,16] width:216 height:37
	dropDownList ddlForm "Format" items:#("Float32", "Float16", "Int32") selection:2 pos:[240,32] width:112 height:40 
	button btnSet "Set Selected" pos:[56,536] width:128 height:32
	dropDownList ddlType "Type" items:#("RGBA", "RGB", "Mono") selection:2 pos:[240,80] width:112 height:40
	dropDownList ddlComp "Compression" items:#("None", "RLE", "ZIPS","ZIP","PIZ","PXR24","B44","B44A") selection:3 pos:[240,128] width:112 height:40
	dropDownList ddlStor "Storage Type" items:#("Scanlines","Tiles") selection:1 pos:[240,176] width:112 height:40
	dropDownList ddlReg "Image Region" items:#("Full","Region") selection:2 pos:[240,224] width:112 height:40
	
	on btnSet pressed do
	(
		bDlg = renderSceneDialog.isOpen()
		renderSceneDialog.close()
		
		iForm = ddlForm.selection - 1
		iType  = ddlType.selection - 1
		iComp = ddlComp.selection - 1
		if (ddlStor.selection - 1) == 0 then bStor = true else bStor = false
		if (ddlReg.selection - 1) == 0 then bReg = false else bReg = true

		
		aSel = (mlbOut.selection as array)
		if aSel.count != 0 do
		(
			for n in aSel do
			(
				fopenexr.setLayerOutputFormat 0 iForm
				fopenexr.setLayerOutputType 0 iType 
				fopenexr.setCompression iComp
				fopenexr.setSaveScanline bStor
				fopenexr.setSaveRegion bReg
				
				fopenexr.setAutoAddRenderElements false  -- !!!!
				
				if n == 1 then
				(
					rendOutputFilename = rendOutputFilename -- not sure if it actually updates like this
				)
				else				
				(
					i = n-2
					elemI = objRmgr.getRenderElement i
					sElem = objRmgr.getRenderElementFilename i
					sElemPath = getFilenamePath sElem
					sElemNew = sElemPath + (i as string) + "_DELETEME" + ".exr"
					makeDir sElemPath
					
					bmTemp = bitmap 1 1 filename:sElemNew gamma:1.0
					save bmTemp
					
					elemI.bitmap = bmTemp
					objRmgr.SetRenderElementFilename i sElem
					
					close bmTemp
					deleteFile sElemNew
				)
			)
		)
		
		if bDlg do renderSceneDialog.open()
	)
)

createDialog dlgSetEXRSettings

[joconnell]

Ah - it might be missing from the 2012 docs perhaps? There wasn't anything available there when I looked at it originally. Must have a run through your script Rens - I never put in the part about writing a temp bitmap into our fileout bits, lazy on my behalf. How's stuttgart treating you?

[Rens]

It think the 2012 docs has them, not the 2011 ones, I'm not sure if they updated them later on or not though. Yeah it's a very peculiar way to go about it, but if it works it works. There isn't really anything in the docs about how to make the settings sticky though.
Stuttgart is good, thanks, how are things in Dublin?

[joconnell]

Busy and constantly evolving! Two friends of mine are both on to their second feature films now so it's looking like some good RnD and then into pre-production early next year. Lots to work on and plenty of software things changing at the minute too!

[cheerioboy]

+1 for this - day,month,year, & time tokens would be what I would use. Oh and the camera/view name? Is that even possible? Is it possible with max script?

At that point I could just run through my cameras firing off renders to the farm and not worry about renaming new versions and also not having to change the output name as I go through the list.

[date %y%m%d]_[%camera]_[time %h%m%s].exr

::drool::

[flat]

+1
Its is useful.

[kagemaru]

About the original request of this topic: can someone confirm that it is still impossible even with vray3 to output render elements in separated folder when using VFB?
It would make my life so much easier with my colleagues

[tashko.zashev]

About the original request of this topic: can someone confirm that it is still impossible even with vray3 to output render elements in separated folder when using VFB?
It would make my life so much easier with my colleagues

Unfortunately it is not implemented yet. I will make a note to the relevant request in our system.

[KiboOst]

Related topic : http://forums.chaosgroup.com/showthr...renderelements

Actually, I find really astonishing how VRay is powerfull and can be so tricky on saving our render files !

[flat]

Isn't this feature implemented yet?